BLOGS BY TOPIC
BLOGS BY AUTHOR
BLOGS BY YEAR
This is part of our full Excel VBA tutorial - Wise Owl also run courses in Excel, as well as classroom training in VBA programming.
Posted by Andy Brown on 02 November 2012
You need a minimum screen resolution of about 700 pixels width to see our blogs. This is because they contain diagrams and tables which would not be viewable easily on a mobile phone or small laptop. Please use a larger tablet, notebook or desktop computer, or change your screen resolution settings.
Using VBA to Link to Internet Explorer
I've shamelessly stolen my colleague Andrew's idea to create this blog, showing how to fill in an Internet Explorer (IE) form from within VBA. I've also shamelessly borrowed ideas from Fergus Cairns - thanks, Fergus.
We'll create a macro in VBA to fill in the search form on the old Wise Owl site (now superseded, but the principle remains the same).
Note that our website has changed since this blog was written, so while the principle of the code shown below is still good, it won't work on our site. I've published a newer blog on the same subject here - or you can see a full list of all of our VBA training resources here.
Understanding the Target Page
The first thing to do is to know what the elements on the target website page are called. To do this, load the website in IE and view its source HTML:
In Internet Explorer 9, this is how you view source HTML using the right mouse button menu.
If you press CTRL + F to find some known text (eg Search for this page), you should be able - eventually - to track down the part of the form of interest:
The HTML for the search button on the Wise Owl website.
See the end of this blog for the BBC and Google UK search form field names.
From the above we can see that the search form with id search contains two controls which a user can interact with:
- A textbox called SearchBox; and
- A button called submit2.
Now that we know what we're trying to look to in the Document Object Model, we can start writing our VBA.
Referencing the Microsoft Internet Controls
The next thing to do is to make sure that we can get VBA to talk to Internet Explorer. To do this, reference the object library called Microsoft Internet Controls (if you're not sure what references are, read this first).
First, in VBA create a reference:
Choose the option shown from the VBA code editor (this example is for Excel).
Select Microsoft Internet Controls (you may find it helpful to type an M in first, to go down to the object libraries starting with M):
Tick the Microsoft Internet Controls object library reference
Select OK. If you choose the menu option again, you'll see this reference has moved to near the top of the list:
The libraries referenced always include Excel. The one you just chose appears near the top of the list.
The Code to Link to IE
You can now write the code to link to Internet Explorer - here's a suggestion:
Sub UseInternetExplorer()
'Make sure you've set a reference to the
'Microsoft Internet Controls object library first
'create a variable to refer to an IE application, and
'start up a new copy of IE (you could use GetObject
'to access an existing copy of you already had one open)
Dim ieApp As New SHDocVw.InternetExplorer
'make sure you can see this new copy of IE!
ieApp.Visible = True
'go to the website of interest
ieApp.Navigate "Wise Owl or other website address goes here"
'wait for page to finish loading
Do While ieApp.busy
Loop
'get a reference to the search form, by finding its id in the
'web page's document object model
Dim ieElement As Object
Set ieElement = ieApp.document.getElementByID("search")
'search box is composed of text box (item 0) and button (item 1)
'set value of text box to what we're searching for
ieElement(0).Value = "Excel VBA courses"
'click the button!
ieElement(1).Click
End Sub
If you run this macro, it should search the Wise Owl site for information on Excel VBA courses!
Except that it might not - timing is everything. You may need to delay your code to wait for Internet Explorer or your website to catch up - see below.
Delaying your code
Unfortunately, code runs really quickly and websites load slowly (at least relatively), so you often need to slow your code down with loops like this:
'wait for page to finish loading
Do While ieApp.Busy
DoEvents
Loop
Or possibly even this:
'wait for page to finish loading
Do While ieApp.Busy And Not ieApp.ReadyState = READYSTATE_COMPLETE
DoEvents
Loop
It seems to be more or less guesswork how many you put in!
BBC and Google Help
Fergus Cairns informs me that you can substitute the following terms for the BBC website and Google UK:
So at the time of writing this (September 2014) the following code works - usually!
Sub FillInBBCSearchForm()
'Make sure you've set a reference to the
'Microsoft Internet Controls object library first
'create a variable to refer to an IE application
Dim ieApp As New SHDocVw.InternetExplorer
'make sure you can see this new copy of IE!
ieApp.Visible = True
'go to the website of interest
ieApp.Navigate "http://www.google.co.uk"
Do While ieApp.Busy
DoEvents
Loop
'wait for page to finish loading
Do While ieApp.Busy And Not ieApp.ReadyState = READYSTATE_COMPLETE
DoEvents
Loop
'fill in the search form
ieApp.Document.getElementById("gbqfq").Value = "Excel VBA"
'wait for page to finish loading
Do While ieApp.Busy
DoEvents
Loop
'wait for page to finish loading
Do While ieApp.Busy And Not ieApp.ReadyState = READYSTATE_COMPLETE
DoEvents
Loop
'click on the search button
ieApp.Document.all("btnG").Click
End Sub
Notice that I've put in a fairly random number of loops to slow this down!
Thank you so much for the excellent VBA posts and videos!
My question is this - is there no way to program VBA to just wait until IE is finished loading, and then execute the next line of code? What if the load time varies?
VBA only knows about what's going on inside one Office application, so can't detect events happening in Windows or a browser. What you could probably do is to write a Windows API call to detect when an Internet Explorer thread has finished, but to be honest I don't know if this is possible, nor if it is how to go about it!